Cálculo del número de días laborales o festivos

Con el siguiente código se calcula el número de días laborables entre dos fechas. Si se le pasan los argumentos opcionales NombreTablaFestivos y NombreCampoFestivo, tiene también en cuenta los días festivos que estén guardados en un campo con nombre NombreCampoFestivo en la tabla con nombre NombreTablaFestivos.

Public Function DiasLaborables(FechaDesde As Date, FechaHasta As Date, Optional NombreTablaFestivos As String, Optional NombreCampoFestivo As String) As Long
Dim Laborables As Long
On Error GoTo DiasLaborables_Error
Laborables = 1 + (FechaHasta - FechaDesde)
If NombreTablaFestivos <> "" And NombreCampoFestivo <> "" Then
Laborables = Laborables - DCount("*", NombreTablaFestivos, "[" & NombreCampoFestivo & "] Between #" & Format(FechaDesde, "mm/dd/yyyy") & "# AND #" & Format(FechaHasta, "mm/dd/yyyy") & "#")
End If
Laborables = Laborables - DateDiff("ww", FechaDesde, FechaHasta, vbSaturday)
Laborables = Laborables - DateDiff("ww", FechaDesde, FechaHasta, vbSunday)
Laborables = Laborables + (Weekday(FechaDesde, vbSunday) = 1)
Laborables = Laborables + (Weekday(FechaDesde, vbSaturday) = 1)
DiasLaborables = Laborables
On Error GoTo 0
Exit Function
DiasLaborables_Error:
MsgBox "Error " & Err.Number & " (" & Err.Description &") in procedure DiasLaborables"
End Function

La función WeekendDays calcula la suma de sábados y domingos entre dos fechas sin utilizar ni bucles ni funciones de fecha.

Public Function WeekendDays(DateStart As Date, DateEnd As Date) As Long
Dim TotalDias As Long, SemanasCompletas As Long, RestoDias As Long, wdResto As Long, wkd As Long
TotalDias = 1 + DateEnd - DateStart
SemanasCompletas = TotalDias \ 7
RestoDias = TotalDias Mod 7
'Calculamos el día de la semana del primer día del resto
'wdResto = Weekday(DateEnd - (RestoDias - 1), vbMonday)
'Como no quiero usar funciones de fecha, en vez de la línea anterioruso la siguiente
wdResto = 1 + ((DateEnd - (RestoDias - 1) + 5) Mod 7)
wkd = SemanasCompletas * 2
'Si el resto de días + el día de la semana (empezando en lunes) es mayor que 6, nos
' cabe un sábado y, si además es mayor que 7, nos cabe un domingo.
If RestoDias > 0 Then
If (RestoDias + wdResto > 6) Then wkd = wkd + 1
If (RestoDias > 1) And (RestoDias + wdResto > 7) And _
(Weekday(DateStart) <> 1) Then wkd = wkd + 1
End If
WeekendDays = wkd
End Function

Una de las formas más directas de calcular sábados y domingos entre dos fechas es comprobar con DateDif (”ww”…) cuántas semanas hay que empiezan por sábado y cuántas que empiecen por domingo y sumarle uno más si la primera fecha para el cálculo es sábado o domingo.

Public Function WeekendDays2(DateStart As Date, DateEnd As Date) As Long
Dim wkd As Long
wkd = DateDiff("ww", DateStart, DateEnd, vbSaturday) + DateDiff("ww", DateStart, DateEnd, vbSunday)
If Weekday(DateStart, vbSunday) = 1 Then wkd = wkd + 1
If Weekday(DateStart, vbSaturday) = 1 Then wkd = wkd + 1
WeekendDays2 = wkd
End Function

Y para terminar basta calcular los días que hay entre dos fechas y restarle los sábados y domingos, que obtenemos con la función WeekEndDays, y los festivos que tenemos en una tabla y que obtenemos con dCount().

Function WorkingDays(DateStart As Date, DateEnd As Date, Optional TableName As String, Optional FieldName As String) As Long
Dim SQL As String
Dim Holidays As Long
If DateStart < DateEnd Then
On Error Resume Next
Holidays = DCount("*", TableName, "[" & FieldName & "] Between #" & Format(DateStart, "mm/dd/yyyy") & " AND #" & Format(DateEnd, "mm/dd/yyyy") & "#")
Err.Clear
WorkingDays = (DateEnd - DateStart) - (Holidays + WeekendDays(DateStart, DateEnd))
End If
End Function

Fuente: Utilidades Access